Trong hình thức nhật ký chung, kế toán phải lập bảng cân đối số phát sinh trước khi lập báo cáo tài chính. Việc này nhằm mục đích gì và phương pháp lập bảng cân đối số phát sinh trên excel như thế nào? Vui lòng đọc bài viết sau để được hướng dẫn chi tiết.
Nội dung
1. Mục đích của bảng cân đối số phát sinh
Phản ánh tổng quát tình hình đầu kỳ, tăng giảm và hiện có của tất cả các tài khoản tổng hợp mà đơn vị đăng ký sử dụng trong kỳ báo cáo. Số liệu trên Bảng cân đối số phát sinh là căn cứ để kiểm tra việc ghi chép trên sổ kế toán tổng hợp, đồng thời đối chiếu và kiểm soát số liệu ghi trên Báo cáo tài chính.
Cuối tháng, cuối quý, cuối năm, cộng số liệu trên Sổ Cái, lập Bảng cân đối số phát sinh. Sau khi đã kiểm tra đối chiếu khớp đúng, số liệu ghi trên Sổ Cái và bảng tổng hợp chi tiết (được lập từ các Sổ, thẻ kế toán chi tiết) được dùng để lập các Báo cáo tài chính. Về nguyên tắc, Tổng số phát sinh Nợ và Tổng số phát sinh Có trên Bảng cân đối số phát sinh phải bằng Tổng số phát sinh Nợ và Tổng số phát sinh Có trên sổ Nhật ký chung (hoặc sổ Nhật ký chung và các sổ Nhật ký đặc biệt sau khi đã loại trừ số trùng lặp trên các sổ Nhật ký đặc biệt) cùng kỳ.
2. Mẫu biểu, nguồn số liệu và phương pháp lập bảng cân đối số phát sinh
2.1. Mẫu biểu
Bảng cân đối số phát sinh: Mẫu số S06-DN (Ban hành theo Thông tư số 200/2014/TT-BTC Ngày 22/12/2014 của Bộ Tài chính)
2.2. Nguồn số liệu
Bảng cân đối số phát sinh được lập dựa trên Sổ Cái và Bảng cân đối số phát sinh kỳ trước.
Trước khi lập Bảng cân đối số phát sinh phải hoàn thành việc ghi sổ kế toán chi tiết và sổ kế toán tổng hợp; kiểm tra, đối chiếu số liệu giữa các sổ có liên quan.
Trong trường hợp ứng dụng excel để làm kế toán, chúng ta đã tìm hiểu chương 2: Xây dựng nguồn cơ sở dữ liệu. Theo đó, dữ liệu để lập báo cáo này gồm 2 phần:
> Số dư đầu tháng: Lấy dữ liệu từ sheet BDMTK
> Số phát sinh trong tháng: Lấy dữ liệu từ sheet BDK
> Số dư cuối tháng: Được tính toán từ Số dư đầu tháng và Số phát sinh trong tháng
2.3. Phương pháp lập
Trên excel, chúng ta thiết kế bảng cân đối số phát sinh theo hình sau:
Lưu ý: Cột B (loại tài khoản) là cột trung gian chứa thuộc tính phân loại tài khoản giúp xử lý số dư đầu kỳ Nợ, số dư đầu kỳ Có. Sau khi hoàn thiện, chúng ta chỉ cần ẩn (hide) cột này thì báo cáo hoàn toàn đúng mẫu quy định.
2.3.1. Số hiệu và tên tài khoản kế toán
Cột A liệt kê tất cả số hiệu các tài khoản tổng hợp (tài khoản cấp 1) mà doanh nghiệp đăng ký sử dụng trong kỳ theo thứ tự tăng dần từ 111 đến 911. Đồng thời ghi tên tài khoản tương ứng vào cột B.
2.3.2. Số dư đầu tháng
> Nguồn dữ liệu: sheet BDMTK
> Đặc điểm dữ liệu, yêu cầu thông tin và hàm sử dụng xử lý
| STT | Đặc điểm dữ liệu | Yêu cầu thông tin | Hàm sử dụng |
|---|---|---|---|
| 1 | Số dư tài khoản chi tiết đến từng đối tượng | Số dư tài khoản tổng hợp | SUMIF |
| 2 | Số dư không tổ chức riêng cột nợ và cột có | Số dư tổng hợp và trình bày riêng Đầu kỳ Nợ, Đầu kỳ Có | IF, OR, AND, ABS |
> Sử dụng các hàm trên lồng nhau để cung cấp thông tin số dư đầu kỳ như sau:
| Cột | Thông tin | Hàm |
|---|---|---|
| 1 | Số dư đầu kỳ Nợ | =IF(OR(AND(B9="N",SUMIF(SHTK,A9&"*",SDDK)>0),AND(B9="C",SUMIF(SHTK,A9&"*",SDDK)<0)),ABS(SUMIF(SHTK,A9&"*",SDDK)),0) |
| 2 | Số dư đầu kỳ Có | =IF(OR(AND(B9="C",SUMIF(SHTK,A9&"*",SDDK)>0),AND(B9="N",SUMIF(SHTK,A9&"*",SDDK)<0)),ABS(SUMIF(SHTK,A9&"*",SDDK)),0) |
2.3.3. Số phát sinh trong tháng
> Nguồn dữ liệu: sheet BDK
> Đặc điểm dữ liệu, yêu cầu thông tin và hàm sử dụng xử lý
| Đặc điểm dữ liệu | Yêu cầu thông tin | Hàm sử dụng |
|---|---|---|
| Số phát sinh theo từng nghiệp vụ liên quan đến tài khoản chi tiết | Tổng phát sinh trong kỳ của tài khoản tổng hợp | SUMIF |
> Sử dụng hàm để cung cấp thông tin số phát sinh trong kỳ như sau:
| Cột | Thông tin | Hàm |
|---|---|---|
| 3 | Số phát sinh trong kỳ Nợ | =SUMIF(TKGN,A9&"*",STPS) |
| 4 | Số phát sinh trong kỳ Có | =SUMIF(TKGC,A9&"*",STPS) |
2.3.4. Số dư cuối tháng
> Nguồn dữ liệu: Được tính toán từ Số dư đầu tháng và Số phát sinh trong tháng
> Đặc điểm dữ liệu, yêu cầu thông tin và hàm sử dụng xử lý
| Đặc điểm dữ liệu | Yêu cầu thông tin | Hàm sử dụng |
|---|---|---|
| Số dư đầu kỳ, Tổng phát sinh tăng, tổng phát sinh giảm của từng tài khoản đã có sẵn | Nếu số dư cuối kỳ bên Nợ tính ra số âm thì trường hợp này trở thành dư Có và ngược lại | MAX |
> Sử dụng công thức để cung cấp thông tin số dư cuối kỳ như sau:
| Cột | Thông tin | Hàm |
|---|---|---|
| 5 | Số dư cuối kỳ Nợ | =MAX(0,D9+F9-E9-G9) |
| 6 | Số dư cuối kỳ Có | =MAX(0,E9+G9-D9-F9) |
2.3.5. Tính tổng cộng để kiểm tra cân đối và hoàn thiện báo cáo
> Tính tổng cộng
| Số dư Đ.Kỳ Nợ | Số dư Đ.Kỳ Có | Số P.Sinh T.Kỳ Nợ | Số P.Sinh T.Kỳ Có | Số dư C.Kỳ Nợ | Số dư C.Kỳ Có | |
|---|---|---|---|---|---|---|
| 1 | 2 | 3 | 4 | 5 | 6 | |
| Tổng | =SUM(D9:D69) | =SUM(E9:E69) | =SUM(F9:F69) | =SUM(G9:G69) | =SUM(H9:H69) | =SUM(I9:I69) |
> Kiểm tra cân đối
+ Tổng dư nợ đầu kỳ (cột 1) = Tổng dư Có đầu kỳ (cột 2)
+ Tổng dư nợ cuối kỳ (cột 5) = Tổng dư Có cuối kỳ (cột 6)
+ Tổng số phát sinh Nợ (cột 3) = Tổng số phát sinh Có (cột 4) trên Bảng cân đối số phát sinh, đồng thời phải bằng Tổng số phát sinh Nợ và Tổng số phát sinh Có trên sổ Nhật ký chung.
> Hoàn thiện báo cáo
+ Ẩn cột B
+ Đầu báo cáo ghi tên đơn vị, địa chỉ
+ Cuối báo cáo trình bày ngày, các chức danh như hình sau:
Cảm ơn bạn đã đọc bài viết. Khi có vấn đề về dữ liệu kế toán, phần mềm kế toán… Vui lòng để lại bình luận hoặc liên hệ với hothanhthao.com để được hỗ trợ.
Hồ Thanh Thảo
